Using multiple timers in one spell

[Powergoat]

Hello!

I am trying to learn JASS and I've currently created this simple spell (using TT). It's basically just a ball rolling forward. What I want is that if an enemy comes withing the ball (the dummy unit) he should be knocked back for a fixed period of time and then not be able to be knocked back again (by the same "ball"). I'm also trying to make it MUI.

scope Ball initializer init

globals
    private constant integer ABILITY_ID = 'A000'
    private constant integer DUMMY_ID = 'h001'
endglobals

private struct data
    unit cast
    unit u
    player p
    location l
    real x
    real y
    real xl
    real yl
    real a
    real f = 0
endstruct

private function Cond takes nothing returns boolean
    return GetSpellAbilityId() == ABILITY_ID
endfunction

private function Movement takes nothing returns boolean
    local data d = TT_GetData()
    set d.f = d.f + 15
    call SetUnitX(d.u,d.x+d.f*Cos(d.a))
    call SetUnitY(d.u,d.y+d.f*Sin(d.a))
    if GetWidgetLife(d.u)<.405 then
        call d.destroy()
        return true
    endif
    return false
endfunction

private function Action takes nothing returns nothing
    local data d = data.create()
    set d.cast = GetTriggerUnit()
    set d.p = GetOwningPlayer(d.cast)
    set d.x = GetUnitX(d.cast)
    set d.y = GetUnitY(d.cast)
    set d.l = GetSpellTargetLoc()
    set d.xl = GetLocationX(d.l)
    set d.yl = GetLocationY(d.l)
    set d.a = Atan2(d.yl-d.y,d.xl-d.x)
    set d.u = CreateUnit(d.p,DUMMY_ID,d.x,d.y,d.a*180/3.1415)
    call UnitApplyTimedLife(d.u,'BTLF',3.00)
    call TT_Start(function Movement,d)
endfunction

private function init takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(t,function Cond)
    call TriggerAddAction(t,function Action)
endfunction

endscope

 

[Sevion]

Just a word of advice, don't ever use TT. It's deprecated and not nearly as good as T32 and other newer systems.

 

[tooltiperror]

So I'm not exactly sure what the question is.

And like Sevion said, TT is horrible in comparison to today's standards. Consider using TimerUtils or even use T32.

 

[Powergoat]

Alright alright the question was confusingly formulated. I've been trying to learn jass a little and I did that by watching some old DotA spell, hence the use of the "TT" system (since that was used in the spell I used as a reference). I can only guess how to use the timersystems since I really don't understand the code. Here's my first try using the "TimerUtils" system, a targeted jump spell. I would appreciate any feedback regarding leaks and such (lines that are unnecessary, strangly written etc).

scope Jump initializer init

globals
    private constant integer ABILITY_ID = 'A000'
    private constant integer FLY_ID = 'A001'
    private constant string SFX = "Abilities\\Spells\\Orc\\WarStomp\\WarStompCaster.mdl"
    private constant real GRAVITY = 17000
    private constant real TIME = 11
    private constant real VELOCITY = TIME/32*GRAVITY/2
endglobals

private struct Data
    unit u
    location l
    real x
    real y
    real xl
    real yl
    real h
    real a
    real d
    real t = 0
endstruct

private function Movement takes nothing returns boolean
    local timer t = GetExpiredTimer()
    local Data d = GetTimerData(t)
    local real v = d.d/TIME
    set d.t = d.t + 0.03125
    call SetUnitX(d.u,d.x+v*Cos(d.a))
    call SetUnitY(d.u,d.y+v*Sin(d.a))
    set d.x = GetUnitX(d.u)
    set d.y = GetUnitY(d.u)
    if d.h > 0.00 then
        set d.h = (VELOCITY*d.t) - (GRAVITY*d.t*d.t/2)
        call UnitAddAbility(d.u,FLY_ID)
        call SetUnitFlyHeight(d.u,d.h,0.00)
        call UnitRemoveAbility(d.u,FLY_ID)
    else
        set d.h = 0.00
        call DestroyEffect(AddSpecialEffect(SFX,GetUnitX(d.u),GetUnitY(d.u)))
        call TerrainDeformCrater(GetUnitX(d.u),GetUnitY(d.u),96,70,0,true)
        call UnitAddAbility(d.u,FLY_ID)
        call SetUnitFlyHeight(d.u,d.h,0.00)
        call UnitRemoveAbility(d.u,FLY_ID)
        call SetUnitPathing(d.u,true)
        call d.destroy()
        call ReleaseTimer(t)
        set t = null
        return true
    endif
    return false
endfunction

private function Action takes nothing returns nothing
    local Data d = Data.create()
    local timer t = NewTimer()
    set d.u = GetTriggerUnit()
    set d.x = GetUnitX(d.u)
    set d.y = GetUnitY(d.u)
    set d.l = GetSpellTargetLoc()
    set d.xl = GetLocationX(d.l)
    set d.yl = GetLocationY(d.l)
    set d.a = Atan2(d.yl - d.y, d.xl - d.x)
    set d.h = 0.10
    set d.d = SquareRoot((d.y-d.yl)*(d.y-d.yl)+(d.x-d.xl)*(d.x-d.xl))
    call SetUnitPathing(d.u,false)
    call SetTimerData(t,d)
    call TimerStart(t,0.03125,true,function Movement)
    set t = null
endfunction

private function Cond takes nothing returns boolean
    return GetSpellAbilityId() == ABILITY_ID
endfunction

private function init takes nothing returns nothing
    local trigger t = CreateTrigger()
    local integer index = 0
    call TriggerAddCondition(t,function Cond)
    call TriggerAddAction(t,function Action)
    loop
        call TriggerRegisterPlayerUnitEvent(t,Player(index),EVENT_PLAYER_UNIT_SPELL_EFFECT,null)
        set index = index + 1
        exitwhen index == bj_MAX_PLAYERS
    endloop
endfunction

endscope

As for my original question: I guess if I want to start multiple timers in one spell (while keeping the struct information) I just "keep sending" the struct information with the "SetTimerData(t,d) where t is the timer and d is the struct name. Sorry if I'm confusing but my brain hurts after skimming through multiple guides.

EDIT: Also, on a semi-unrelated note, I noticed when I cast this spell (based of channel) that my character "casts" the spell for about 0.5-1 sec and then the trigger starts (even though the follow-through time is set to 0.00). Is there anyway to remove the cast time and make the trigger start the second I click the selected target?

 

[Dirac]

In your case you should use T32 instead since it's faster and more effective when it comes to looping timers that repeat every 0.03125 seconds, also... did you solved the problem? you didn't say at all.

Thats not the casting time, that's the unit's casting animation. Go to the object editor, find the "cast backswing" and "cast point" animations and set them to 0