Boolean expressions and GroupEnum...(...)

[Tom Jones]

I think Blizzard has fixed the bug with passing null as argument, because I can't get this to leak no matter how hard I try:

scope TestFilters initializer Init
globals
    private constant string COMMAND = "-test "
    private constant integer LENGTH = StringLength(COMMAND)
    private constant integer DEDUCT = 0x100000
    
    private group G = CreateGroup()
    private timer T = CreateTimer()
    private real RANGE
    private rect AREA 
    private boolexpr FILTER

    private integer HANDLES = 0
endglobals

private function H2I takes handle h returns integer
    /*return h
    return 0*/
    return GetHandleId(h)
endfunction

private function HandleCount takes nothing returns integer
    set T = CreateTimer()
    set HANDLES = IMaxBJ(H2I(T)-DEDUCT,HANDLES)
    call DestroyTimer(T)
    return HANDLES
endfunction

private function True takes nothing returns boolean
    return true
endfunction

private function Actions takes nothing returns nothing
    local string s = GetEventPlayerChatString()
    local integer i = StringLength(s)
    local string key = StringCase(SubString(s,LENGTH,i),false)

    if S2I(key) == 1 or key == "a" then
        call GroupEnumUnitsInRange(G,0,0,RANGE,Condition(function True))
        call GroupEnumUnitsInRect(G,AREA,Condition(function True))
        call GroupEnumUnitsOfPlayer(G,Player(0),Condition(function True))
    elseif S2I(key) == 2 or key == "b" then
        call GroupEnumUnitsInRange(G,0,0,RANGE,FILTER)
        call GroupEnumUnitsInRect(G,AREA,FILTER)
        call GroupEnumUnitsOfPlayer(G,Player(0),FILTER)
    elseif S2I(key) == 3 or key == "c" then
        call GroupEnumUnitsInRange(G,0,0,RANGE,null)
        call GroupEnumUnitsInRect(G,AREA,null)
        call GroupEnumUnitsOfPlayer(G,Player(0),null)
    else
        call BJDebugMsg("Bad input: "+key)
        return
    endif
    call BJDebugMsg("\n###################\n#Test "+key+".\n#HandleCount: "+I2S(HandleCount()))
endfunction

private function Init takes nothing returns nothing
    local trigger trig = CreateTrigger()
    
    set FILTER = Condition(function True)
    set RANGE = GetRectMaxX(bj_mapInitialPlayableArea)-GetRectMinX(bj_mapInitialPlayableArea)
    set AREA = Rect(GetRectMinX(bj_mapInitialPlayableArea),GetRectMinY(bj_mapInitialPlayableArea),GetRectMaxX(bj_mapInitialPlayableArea),GetRectMaxX(bj_mapInitialPlayableArea))
    
    call TriggerRegisterPlayerChatEvent(trig,Player(0),COMMAND,false)
    call TriggerAddAction(trig,function Actions)
endfunction
endscope

Or maybe I'm simply performing the test wrong.

 

[jwallstone]

Wow, Blizzard actually making progress on memory leaks, that would be great! I'm assuming you're using the latest patch 1.24?

Have you double checked that the units placed belong to Player(0)? Also, doesn't the group G need to be cleared between use?

I'm curious: why do you use Condition() instead of Filter(), and why do you create a new rect instead of just using bj_mapInitialPlayableArea?

Congrats on 3000 posts!

 

[chobibo]

scope test initializer init

globals
    group GROUP
    timer TIMER
    integer HANDLE_OFFSET
    integer TEST_N
    integer TEST_MAX=1000
endglobals

private function StartTest takes nothing returns nothing
    call GroupEnumUnitsInRange(GROUP, 0, 0, 1000, null)
    set TEST_N=TEST_N+1
    call TimerStart(TIMER, 0.01, TEST_N<TEST_MAX, function StartTest)
endfunction

private function DisplayTestResult takes nothing returns nothing
    local trigger t=CreateTrigger()
    local integer n=GetHandleId(t)
    call DestroyTrigger(t)
    set t=null
    call BJDebugMsg("HANDLE's created: "+I2S((n-HANDLE_OFFSET)+1))
endfunction

private function init takes nothing returns nothing
    set GROUP=CreateGroup()
    set TIMER=CreateTimer()
    set HANDLE_OFFSET=GetHandleId(GROUP)
    set TEST_N=0
    
    call TimerStart(TIMER, 2.5, false, function StartTest)
    call TimerStart(CreateTimer(), 5, false, function DisplayTestResult)
endfunction

endscope

I got no handle leaks.

 

[Tom Jones]

Wow, Blizzard actually making progress on memory leaks, that would be great! I'm assuming you're using the latest patch 1.24?

Have you double checked that the units placed belong to Player(0)?

Yep.

Also, doesn't the group G need to be cleared between use?

It's global.

I'm curious: why do you use Condition() instead of Filter(). And why do you create a new rect instead of just using bj_mapInitialPlayableArea?

Old habits.

Congrats on 3000 posts!

Thanks mate.

I got no handle leaks.

This seems to confirm what I expected.

 

[jwallstone]

According to someone here though, the problem is not a handle leak but rather increasing memory utilization:
http://www.wc3c.net/showthread.php?t=106951

Regarding the group G, I meant to ask if you need to call GroupClear(G) between use? Or does each use of GroupEnum*** automatically remove the previous units? For example, in the Blizzard functions (like GetUnitsOfTypeIdAll), they call GroupClear between repeated uses of GroupEnum, which I presumed was because GroupEnum adds additional units but doesn't remove the old ones.

 

[Jesus4Lyf]

Yep. This never leaked handles.