Snippet Rawcode Hashing

[Strilanc]

Storing values into arrays at position 8191 reportedly causes save games to fail.

I don't really get why you feel it's wrong to return 0. There's no error case here that would necessitate checking the return value. The entry either exists or is created, whether or not its index is 0. You're already breaking 'proper' struct procedure by not using create or destroy.

 

[Jesus4Lyf]

>Storing values into arrays at position 8191 reportedly causes save games to fail.
That's why I made it 8190. But, I suppose I can do 0-8190 for 8191 values...

>You're already breaking 'proper' struct procedure
I see no structs.

Updated. 0-8190 appears to be the most appropriate solution.

 

[Strilanc]

Sorry, I was thinking about my own PAM system, which has a similar mechanism but different way to store data.

 

[Hatebreeder]

Wouldn't you be making a attachment System?
with a Boolean Check, you could recreate TimerTicker or ABC or something?

 

[Tyrande_ma3x]

> The HashRelease function is for when you no longer will use an integer, kind of like flushing a table.
Uh, what? Where is this thing?

 

[Jesus4Lyf]

>Wouldn't you be making a attachment System?
>with a Boolean Check, you could recreate TimerTicker or ABC or something?
Eh? I don't think I'm sure what you mean. This is pretty much the core of an attaching system. Using this makes it easy for people to attach to whatever. Just copy/paste...

>Where is this thing?
Oops, removed that.

 

[Jesus4Lyf]

Just wrote a hashing algorithm for releasing as well, if anyone is interested:

private struct HashIndex
    thistype next=0
    integer hashedInt
endstruct
globals
    private constant integer MAX_HASH_VALUE=8191
    //===================================
    private HashIndex array ListOnHash
endglobals
private function Hash takes integer int returns integer
    local HashIndex hash=HashIndex(int-(int/MAX_HASH_VALUE)*MAX_HASH_VALUE)
    if ListOnHash[hash]==0 then
        set ListOnHash[hash]=HashIndex.create()
        set hash=ListOnHash[hash]
        set hash.hashedInt=int
    else
        set hash=ListOnHash[hash]
        loop
            exitwhen hash.hashedInt==int
            if hash.next==0 then
                set hash.next=HashIndex.create()
                set hash=hash.next
                set hash.hashedInt=int
                return hash
            endif
            set hash=hash.next
        endloop
    endif
    return hash
endfunction
private function HashFree takes integer int returns nothing
    local HashIndex hash=HashIndex(int-(int/MAX_HASH_VALUE)*MAX_HASH_VALUE)
    local HashIndex last=ListOnHash[hash]
    if last.hashedInt==int then
        set ListOnHash[hash]=last.next
        call last.destroy()
    else
        loop
            set hash=last.next
            exitwhen hash==0 // Shouldn't happen. Safety first, though.
            if hash.hashedInt==int then
                set last.next=hash.next
                call hash.destroy()
                return
            endif
            set last=hash
        endloop
    endif
endfunction

 

[Nestharus]

Sooo, how often will rawcode hashing beat out hashtables o-o...


"ponders"

 

[RaiJin]

lol never did get to thank you for this

ill try to rep <_< after the spread thing stops lol anyhow thanks a bunch for this helped:thup: a lot

EDIT:haha rep worked

 

[Romek]

As I've said multiple times before.
This is not comparable to hashtables.
Comparing this to hashtables is the equivalent of comparing ModuloInt to Gamecache.

Anyway, this is quite a useful little snippet. I'm not sure how usable it is, as a regular modulo probably won't have collisions until there are 8191 handles (assuming this is used for hashing GetHandleId(a)).

But, when collisions are probable (In raw codes, for example), this is good.

Approved.

Also, you can remove the old script. ^_^

 

[Troll-Brain]

Time for benchmark it :

library Hashing initializer init

globals
    private constant integer HASH_NEXT=53
    private constant integer MAX_HASH_VALUE=8191
    //===================================
    private integer array HashedInt
    // for the benchmark
    public hashtable Hasht
endglobals

function Hash takes integer int returns integer
    local integer hash=int-(int/MAX_HASH_VALUE)*MAX_HASH_VALUE
    loop
        exitwhen HashedInt[hash]==int
        if HashedInt[hash]==0 then
            set HashedInt[hash]=int
            return hash
        endif
        set hash=hash+HASH_NEXT
        if hash>=MAX_HASH_VALUE then
            set hash=hash-MAX_HASH_VALUE
        endif
    endloop
    return hash
endfunction

private function init takes nothing returns nothing
    set Hasht = InitHashtable()
endfunction

endlibrary

library Benchmark initializer init uses Hashing

globals
    private real T1 = 0.
    private real T2 = 0.
    private real T3 = 0.
endglobals

private function Actions takes nothing returns nothing
    local integer sw = StopWatchCreate()

    local integer i = 0
    local integer j = 0

    local real t0 = 0.
    local real t1 = 0.

    call BJDebugMsg(" ")
    
    set t0 = StopWatchMark(sw)
    
    loop
    exitwhen i == 200
    
        set i = i+1
        call SaveInteger(Hashing_Hasht,0,i,i)
        
    endloop
    
    set t1 = StopWatchMark(sw)
    
    call BJDebugMsg("set Hashtable ; " + R2S((t1-t0)*10000.))
    
    set i = 0
    
    set t0 = StopWatchMark(sw)
    
    loop
    exitwhen i == 200
    
        set i = i+1
        call Hash(i)
        
    endloop
    
    set t1 = StopWatchMark(sw)
    
    call BJDebugMsg("set Hashing ; " + R2S((t1-t0)*10000.))
    
    set i = 0
    
    set t0 = StopWatchMark(sw)
    
    loop
    exitwhen i == 200
    
        set i = i+1
        set j = LoadInteger(Hashing_Hasht,0,i)
        
    endloop
    
    set t1 = StopWatchMark(sw)
    
    call BJDebugMsg("get Hashtable ; " + R2S((t1-t0)*10000.))
    
    set i = 0
    
    set t0 = StopWatchMark(sw)
    
    loop
    exitwhen i == 200
    
        set i = i+1
        set j = Hash(i)
        
    endloop
    
    set t1 = StopWatchMark(sw)
    
    call BJDebugMsg("get Hashing ; " + R2S((t1-t0)*10000.))
    
    call StopWatchDestroy(sw)

endfunction

//===========================================================================
private function init takes nothing returns nothing
    local trigger trig = CreateTrigger(  )
    call TriggerRegisterPlayerChatEvent( trig, Player(0), "test", true )
    call TriggerAddAction( trig, function Actions )
endfunction

endlibrary

Hashtables seems almost 3 times faster than your function.

 

[Jesus4Lyf]

Ah cool. I'll benchmark this also when I get a chance. If it's 3 times slower it's pretty useless.

(This was released before 1.24.)

 

[Troll-Brain]

Yes it is, also i'm surprised that if you use a global instead of a local (hash) the difference is irrevelant.
Also it becomes more slower with more hashs (pretty obvious)