Troubles with lightning effect

[inevit4ble]

Hi Every1,

Just starting out with jass and was going good until this lightning effect won't change color or destroy. I assume I'm setting the variable incorrectly. Could someone correct me please?

scope HealingBolt initializer Cast

function Missile takes location l, location ll returns nothing
    local lightning g
    
    call AddLightningEx("AFOD", true, GetLocationX(l), GetLocationY(l), GetLocationZ(l), GetLocationX(ll), GetLocationY(ll), GetLocationZ(ll))
    set g = bj_lastCreatedLightning
    call SetLightningColor( g, 0, 1, 0, 1)
    call TriggerSleepAction(0.1)
    call DestroyLightning(g)
endfunction    

function Heal takes real r, real rr returns real
    return r+rr
endfunction
    
function AbiCheck takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A000' ) ) then
        return false
    endif
    return true
endfunction

function Effects takes nothing returns nothing
    local real newhp
    local location from = GetUnitLoc(GetTriggerUnit())
    local location to = GetUnitLoc(GetSpellTargetUnit())
    
    call AddSpecialEffectTarget("Abilities\\Spells\\NightElf\\Blink\\BlinkCaster.mdl", GetTriggerUnit(), "origin")
    call DestroyEffect(bj_lastCreatedEffect)
    call Missile(from, to)
    call UnitDamageTarget(GetTriggerUnit(), GetSpellTargetUnit(), 300.00, true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_WHOKNOWS)
    set newhp = Heal(GetUnitState(GetTriggerUnit(), UNIT_STATE_LIFE), 50.00)
    call SetUnitState(GetTriggerUnit(), UNIT_STATE_LIFE, newhp)
endfunction

function Cast takes nothing returns nothing
    local trigger t
    local trigger tt
    local integer i = 0
    
    set t = CreateTrigger()
        loop
            call TriggerRegisterPlayerUnitEvent( t, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
            set i = i + 1
            exitwhen i == bj_MAX_PLAYER_SLOTS
        endloop
    call TriggerAddCondition( t, Condition( function AbiCheck ) )
    call TriggerAddAction( t, function Effects )
endfunction
endscope

PS. This is my first jass trigger I've made so if there are additional errors or things I should be doing please inform me so I can learn the right way from the beginning.

THANKS

 

[luorax]

Only BJ function give value to bj_XYZ variables, such as [ljass]bj_lastCreatedLightning[/ljass].

Do this instead:

set g=AddLightningEx("AFOD", true, GetLocationX(l), GetLocationY(l), GetLocationZ(l), GetLocationX(ll), GetLocationY(ll), GetLocationZ(ll))

The same goes for the effect variable in function "Effects"

EDIT: also, leaks.

It should be something like this:

scope HealingBolt initializer Cast

function Missile takes location l, location l2 returns nothing
    local lightning g=AddLightningEx("AFOD", true, GetLocationX(l), GetLocationY(l), GetLocationZ(l), GetLocationX(l2), GetLocationY(l2), GetLocationZ(l2))
    call SetLightningColor( g, 0, 1, 0, 1)
    call TriggerSleepAction(0.1)
    call DestroyLightning(g)
    set g=null
endfunction    

function Heal takes real r, real r2 returns real
    return r+r2
endfunction
    
function AbiCheck takes nothing returns boolean
    return GetSpellAbilityId() == 'A000'
endfunction

function Effects takes nothing returns nothing
    local real newhp
    local location from = GetUnitLoc(GetTriggerUnit())
    local location to = GetUnitLoc(GetSpellTargetUnit())
    
    call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\NightElf\\Blink\\BlinkCaster.mdl", GetTriggerUnit(), "origin"))
    call Missile(from, to)
    call UnitDamageTarget(GetTriggerUnit(), GetSpellTargetUnit(), 300.00, true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_WHOKNOWS)
    set newhp = Heal(GetUnitState(GetTriggerUnit(), UNIT_STATE_LIFE), 50.00)
    call SetUnitState(GetTriggerUnit(), UNIT_STATE_LIFE, newhp)
    
    call RemoveLocation(from)
    call RemoveLocation(to)
    set from=null
    set to=null
endfunction

function Cast takes nothing returns nothing
    local trigger t
    local integer i = 0
    
    set t = CreateTrigger()
        loop
            call TriggerRegisterPlayerUnitEvent( t, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
            set i = i + 1
            exitwhen i == bj_MAX_PLAYER_SLOTS
        endloop
    call TriggerAddCondition( t, Condition( function AbiCheck ) )
    call TriggerAddAction( t, function Effects )
    
    set t=null
endfunction
endscope

Also, you shold learn how to use reals instead of locations (however this is your first JASS trigger ever, so just step by step)

 

[inevit4ble]

Ok cool. That worked

Some more questions:

1)After I copied the amended script the Damage to TargetUnit didn't occur so I set the units to locals and used those instead then it worked. I would guess thats because now the "missile" function ran and the wait messed with "GetSpellTargetUnit" (same as GUI)?

2)I noticed that catching the leaks didn't only require the locations being destroyed but also to be set = null. Is that what should be done with all leaking variables?

3)Using reals rather than locations would mean I wouldn't have leaks to begin with?

4)How would I go about using reals in place of location? Set each X;Y;Z via GetUnitX;Y;Z?

 

[luorax]

1, Dunno to be honest, I always avoided TriggerSleepActions - I prefer timers instead. TriggerSleepAction likes causing errors.

2, You only have to null handles, like unit, player, location, effect, etc. Integers/Reals/Strings (Structs are integers -> you don't have to null them) are deallocated automatically.

3, Exactly. Because you don't have to null reals, you can not leak. You can always use [ljass]GetSpellTargetX[/ljass], [ljass]GetSpellTargetY[/ljass], [ljass]GetUnitX[/ljass] and [ljass]GetUnitY[/ljass]. (And also, locations are basically "structs" with an X,Y and Z member)

4, Exactly. However there's no [ljass]GetUnitZ[/ljass] function, you have to create your own:

//: ==============================================
    //:                GetZ()
    //: ==============================================
    
    globals
        private location ZLoc=Location(0.,0.)
    endglobals
    function GetUnitZ takes unit u returns real
        call MoveLocation(ZLoc,GetUnitX(u),GetUnitY(u))
        return GetLocationZ(ZLoc)+GetUnitFlyHeight(u)
    endfunction
    
    function GetPointZ takes real x,real y returns real
        call MoveLocation(ZLoc,x,y)
        return GetLocationZ(ZLoc)
    endfunction

Place this in a library (I like my own "MiscFunctions" library) or in the map header.

 

[inevit4ble]

Sweet! Thanks for clarify all that stuff for me. Hopefully I wont run into too many problems while I'm experimenting

Place this in a library (I like my own "MiscFunctions" library) or in the map header.

I'll do that once I learn more about them...lol

 

[Dirac]

I just want to point out that it's good to see a GUI user learn JASS.

One last tip, you can initialize the variables directly when creating them as locals. Ex:

local unit u=CreateUnit(p,t,x,y,a)

 

[luorax]

He already told me once in PM that he's learning JASS. I felt the same - one more mate. vJASS (and programming in general) is soo awesome and funny.

Also, take a look at this tutorial. This will show you how to use namespaces (scope and library) properly.
And practice, practice, and practice even more! That's the way to become a good JASSer.

 

[inevit4ble]

@Dirac: I reckon thats to optimize the code. Will try do it where I can.

@luorax: That tutorial looks quite promising. I will work through it and see what I can come up with