2 questions simple (or not)

[Laiev]

1 - what is more fast to check some unit (or more safe/better): array, group or hashtable (or anything else)

if IsUnitInGroup(g, u) then //~
if Unit[1] == u then //~
//hashtable ~ don't know how use it..

2 - a struct can extand 2 or more other structs?

struct a
endstruct

struct b
endstruct

struct c extends a, b //??
endstruct

 

[luorax]

1, Arrays are faster than hashtables as i know.
2, Ehh, i never tried to do it, but i think you can. But you could simple test it.

 

[Tamisrah]

2. You can't do that. But look at the delegate feature or maybe interfaces. I'm not too sure what you actually want to achieve.

 

[Laiev]

I just want to know if i can extend 2 things at the same time |:

can you explain a bit how do that with interfaces?

also anyone else know about the group/array part?

and thx both @luorax and @tamisrah for the answer

 

[Accname]

hashtables are usually pretty slow. the array is alot faster for sure, arrays are meant to be effective and fast. that was the very reason for their conception.

 

[Jedi]

Hashtables should be 2x slower than arrays, not much.

 

[Laiev]

i'm asking about array and group because i made a system which check something for the unit...

so i made it in 2 ways...

1 - group (add unit to group - is unit in group)
2 - array (array[GetUnidId(unit)] == true/false)

group is a good way to do it too?

 

[Accname]

i think, but dont take this for granted, that checking whether a unit is in a unit group is pretty slow because it will iterate through the whole group until it finds the specific unit and if it doesnt find it it will return false.

 

[tooltiperror]

The problem is that arrays are not a type in JASS.

You're best bet is to make Arrays a type, so that they can be taken as arguments.

struct UnitArray
unit array arr[8190]
endstruct

//function:
local UnitArray array=UnitArray.create()
set array.arr=GetTriggerUnit()

This becomes useful when you want to take an integer.

 

[kingkingyyk3]

The problem is that arrays are not a type in JASS.

You're best bet is to make Arrays a type, so that they can be taken as arguments.

struct UnitArray
unit array arr[8190]
endstruct

//function:
local UnitArray array=UnitArray.create()
set array.arr=GetTriggerUnit()

This becomes useful when you want to take an integer.

Does not work, apparently.
And slower.

2 - a struct can extand 2 or more other structs?

No, If you wanted to do this, you have to DIY.

 

[Laiev]

DIY?

Do It by Yourself?

 

[Tamisrah]

This is the closest I can think of for double extension.

To see the effect in-game give the unit an immediate order. (ie 'stop')

library DelegateTest
    private struct A
        private effect fx = null
        method attach takes unit u returns boolean
            set .fx = AddSpecialEffectTarget("units\\undead\\Abomination\\Abomination.mdl",u,"overhead")
            if .fx!=null then
                return true
            endif
            return false
        endmethod
        method remove takes nothing returns boolean
            if .fx!=null then
                call DestroyEffect(.fx)
                set .fx = null
                return true
            endif
            return false
        endmethod
    endstruct

    private struct B
        private unit u = null
        method colorize takes unit u returns boolean
            if u!=null then
                set .u = u
                call SetUnitVertexColor(u,0xFF,0x66,0xDD,0xFF)
                return true
            endif
            return false
        endmethod
        method uncolor takes nothing returns boolean
            if .u!=null then
                call SetUnitVertexColor(u,0xFF,0xFF,0xFF,0xFF)
                set .u = null
                return true
            endif
            return false
        endmethod
    endstruct

    private struct C
        private delegate A dA
        private delegate B dB
        
        static method create takes nothing returns thistype
         local thistype this = thistype.allocate()
            set .dA = A.create()
            set .dB = B.create()
            return this
        endmethod
    endstruct

    struct AB extends C
        static thistype CURRENT = 0
        static boolean FLAG = true
        static method onEvent takes nothing returns nothing
         local unit u = GetTriggerUnit()
            if thistype.FLAG then
                call CURRENT.attach(u)
                call CURRENT.colorize(u)
            else
                call CURRENT.remove()
                call CURRENT.uncolor()
            endif
            set thistype.FLAG = not thistype.FLAG
        endmethod
        
        static method onInit takes nothing returns nothing
         local trigger t = CreateTrigger()
            call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_ISSUED_ORDER)
            call TriggerAddAction(t,function thistype.onEvent)
            set thistype.CURRENT = thistype.create()
        endmethod
    endstruct
endlibrary

 

[Laiev]

interesting example o.o

thank you very much