[Function] Animation test by Vex

[waaaks!]

heres a trigger made by vex for showing the animation index of a selected unit
u need only to press esc, then the selected unit will play its animation indexes

it requires cs cache

function AnimationTest_Actions takes nothing returns nothing
 local group g=CreateGroup()
 local player p=GetTriggerPlayer()
 local unit u
 local trigger t
 local string k
 local integer i
 local boolean b
    call GroupEnumUnitsSelected(g,p,null)
    set u=FirstOfGroup(g)

    if (GetTableBoolean("[animtest]", "viewing")) then
        call CinematicModeBJ(false,bj_FORCE_ALL_PLAYERS)
        call SetTableBoolean(GetTableString("[animtest]","current"),"skip",true)
        call SetTableString("[animtest]","current","")
        call SetTableBoolean("[animtest]","viewing",false)
        call ClearTextMessages()
    elseif (u!=null) then
        call CinematicModeBJ(true,bj_FORCE_ALL_PLAYERS)
        call VolumeGroupReset()
        set k=NewTable()
        call SetTableString("[animtest]","current",k)
        call SetTableBoolean("[animtest]","viewing",true)
        call SetCameraPosition(GetUnitX(u),GetUnitY(u))
        call PauseUnit(u,true)
        set b=(GetUnitAbilityLevel(u,'Avul')==0)
        if (b) then
            call UnitAddAbility(u,'Avul')
        endif
        set i=0
        call TriggerSleepAction(0)
        loop
            exitwhen (GetTableBoolean(k,"skip"))
            call ClearTextMessages()

            call BJDebugMsg("Currently playing Animation "+I2S(i)+"\nPress ESC again to exit")

            call SetUnitAnimationByIndex(u,i)
            call PolledWait(3)
            set i=i+1
        endloop
        call PauseUnit(u,false)
        if (b) then
            call UnitRemoveAbility(u,'Avul')
        endif

        call DestroyTable(k)
    else
        call BJDebugMsg("Please select a unit before pressing ESC")
    endif
 call DestroyGroup(g)
 set g=null
 set u=null
endfunction


//===========================================================================
function InitTrig_AnimationTest takes nothing returns nothing
 local integer a=0
    set gg_trg_AnimationTest = CreateTrigger(  )
    loop
        exitwhen (a>11)
        call TriggerRegisterPlayerEventEndCinematic( gg_trg_AnimationTest, Player(a) )
        set a=a+1
    endloop
    call TriggerAddAction( gg_trg_AnimationTest, function AnimationTest_Actions )
endfunction

i hope this helps someone

 

[Hatebreeder]

Why is there an Ability Code in there, is this a Spell or something?
Please explain further. I am new to JASS, and would appriciate it, if you could add some // or briefly explain how to use it properly.

 

[waaaks!]

dont mind that....its a default ability from WE
i think thats the invulnerable ability

just create an ability called
AnimationTest

then convert to custom text and them delete all texts inside the trigger, paste the code in the trigger then save

test the map, click a unit, and press esc

 

[~GaLs~]

Basicly...

I know I am a noob, as I can't see any use of using this trigger to check the animation index.
If we wanted to play the unit's animation, we could use the animation name as it is shown on the previewer of the World Editor.

 

[Uberplayer]

By using that function, you can see what animation index is currently playing.. you cannot see the index from object editor.

You should figure it out already, so I am not trying to explain more.

 

[SFilip]

Well, all this does is turn on cinematic mode and loop through all of the selected unit's animation so that you can find out which ID to use with SetUnitAnimationByIndex.

 

[Uberplayer]

That's what I just said..

trigger named "t" is never nulled by the way.

 

[ReVolver]

I don't think you need to null a trigger, but I never knew.

 

[Uberplayer]

It's a local trigger, which extends handle. I guess it has to be nulled.

Strings don't need to be nulled.
Players don't need to be nulled either.
Unit variables holding heroes don't need to be nulled unless you're going to remove that hero at some point using RemoveUnit.

You only need to null variables that contain something you might destroy. Heroes, players, some other permanent units like shops etc. don't need to be nulled. Remember though that all units are removed around 90 seconds after they die.

Actually, if this all seems too confusing, doesn't hurt to just null 'em all.

From SFilip.

 

[Vexorian]

That's what I just said..

trigger named "t" is never nulled by the way.

It is never assigned either. So it doesn't matter.

This function is for development time only , so it doesn't really matter the amount of flaws it has, the most important one is the "group enum with null boolexpr on local group variable" one. The second worse is the usage of gamecache.

 

[Uberplayer]

Oh, and it also doesn't matter much, if it leaks or has something useless in it, because it's used only for getting the index of wanted animation.. only for testing ..

Edit://Greath..