Immolation
Member
- Reaction score
- 20
Immolate
Because Immolation is not enough.
Surrounds target unit(allied or enemy) with flames, dealing damage each .33 seconds to enemy units near it.
GUI/vJASS= vJASS
Leakless?= Yes.
Lagless= Yes.
MUI/MPI?= MUI
Requires: AIDS, Event, KT2, GT and Damage.
Changelog:
v1.01:
-Improved code.
-Damage configuration now takes damage per second instead of damage per period.
v1.00:
-Initial release.
Code:Because Immolation is not enough.
Surrounds target unit(allied or enemy) with flames, dealing damage each .33 seconds to enemy units near it.
GUI/vJASS= vJASS
Leakless?= Yes.
Lagless= Yes.
MUI/MPI?= MUI
Requires: AIDS, Event, KT2, GT and Damage.
Changelog:
v1.01:
-Improved code.
-Damage configuration now takes damage per second instead of damage per period.
v1.00:
-Initial release.
JASS:
scope Immolate initializer Init
//-------------------------------------------------------------
// Immolate by Immolation
//-------------------------------------------------------------
// Description:
//---------------------------
//Surrounds target unit(allied or enemy) with flames, dealing damage each .33 seconds to enemy units near it.
// What do I need to import it in my map?
//---------------------------
// You need to download JASS NewGen, available at the following links:
//
// -http://www.thehelper.net/forums/showthread.php?t=73936
// -http://www.wc3c.net/showthread.php?t=90999
//
//Install it and then read the following paragraph.
// How do I put it in my map?
//---------------------------
// 1. Copy:
// a. Copy the Ability found in the Abilities tab in the Object Editor.
// b. Copy all this trigger and those you find in the Systems category.
// Check the Damage and AIDS triggers for implementation instructions about those systems.
// 2. Press CTRL + D while in Abilities section in Object Editor to find out the rawcode of:
// a. The "Immolate" ability. Change the ABILITY_ID to the rawcode that you find(it's 'A000' in this map).
// 3. You have succesfully imported the spell <img src="data:image/gif;base64,R0lGODlhAQABAIAAAAAAAP///yH5BAEAAAAALAAAAAABAAEAAAIBRAA7" class="smilie smilie--sprite smilie--sprite8" alt=":D" title="Big Grin :D" loading="lazy" data-shortname=":D" />
// Changelog:
//---------------------------
// v1.01
// -Improved code.
// -Damage configuration now takes damage per second instead of damage per period.
// v1.00
// -Initial release.
//---------------------------
// TheHelper.net
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
// LIST OF CONFIGURABLES
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
globals
//Rawcodes:
private constant integer ABILITY_ID = 039;A000039;
//Effects:
private constant string EFFECT_TARGET = "Abilities\\Spells\\Other\\ImmolationRed\\ImmolationRedTarget.mdl"
private constant string EFFECT_TARGET_ATTACHMENT = "chest"
private constant string EFFECT = "Abilities\\Spells\\Items\\AIfb\\AIfbSpecialArt.mdl"
private constant string EFFECT_ATTACHMENT = "chest"
endglobals
private function Duration takes integer Level returns real
return 10.00
endfunction
private function Period takes integer Level returns real
return 0.33
endfunction
private function DamagePerSecond takes integer Level returns real
return 15.00 * Level //Damage per second.
endfunction
private function Area takes integer Level returns real
return 200.00
endfunction
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
native UnitAlive takes unit id returns boolean
private struct Immolate
unit caster
unit target
integer level
integer ticks
effect sfx
real range
real dmg
endstruct
globals
private group GROUP = CreateGroup()
private unit Caster
private real Damage
endglobals
private function GroupCallback takes nothing returns boolean
local unit target = GetFilterUnit()
if IsUnitEnemy(Caster, GetOwningPlayer(target)) == true and UnitAlive(target) == true /*
*/ and IsUnitType(target, UNIT_TYPE_STRUCTURE) == false then
call DestroyEffect(AddSpecialEffectTarget(EFFECT, target, EFFECT_ATTACHMENT))
call Damage_Spell(Caster, target, Damage)
endif
set target = null
return false
endfunction
private function TimerCallback takes nothing returns boolean
local Immolate A = KT_GetData()
if A.ticks == 0 or UnitAlive(A.target) == false then
call DestroyEffect(A.sfx)
call A.destroy()
return true
endif
set Caster = A.caster
set Damage = A.dmg
set A.ticks = A.ticks - 1
call GroupEnumUnitsInRange(GROUP, GetUnitX(A.target), GetUnitY(A.target), A.range, Filter(function GroupCallback))
return false
endfunction
private function Main takes nothing returns boolean
local Immolate A = Immolate.create()
set A.caster = GetTriggerUnit()
set A.target = GetSpellTargetUnit()
set A.level = GetUnitAbilityLevel(A.caster, ABILITY_ID)
set A.dmg = DamagePerSecond(A.level) * Period(A.level)
set A.range = Area(A.level)
set A.ticks = R2I(Duration(A.level) / Period(A.level))
set A.sfx = AddSpecialEffectTarget(EFFECT_TARGET, A.target, EFFECT_TARGET_ATTACHMENT)
call KT_Add(function TimerCallback, A, Period(A.level))
return false
endfunction
//===========================================================================
private function Init takes nothing returns nothing
call GT_AddStartsEffectAction(function Main, ABILITY_ID)
endfunction
endscope