Anyone care to explain timer usage...?

[Azlier]

Well, it's not like Stuff even runs unless you call TriggerExecute on your trigger.

That Run on Map Initialization box doesn't work for local triggers.

I don't even see why myFunct should run.

 

[Lyerae]

Wait, what?
Why wouldn't it run?

 

[Azlier]

Is it a library/scope initializer?

 

[Lyerae]

No...
But I used a GUI trigger with the event as "Map Initialization" to call "Stuff", and it worked, so I guess I figured that out... I think...

 

[Azlier]

Add a debug message in the Stuff function. myFunct, too.

 

[Lyerae]

function Callback takes nothing returns boolean // Only works if I call "Stuff" with a GUI trigger.
    local integer Data = KT_GetData()
    local boolean b = false
    call BJDebugMsg("Just a test, to see if I'm actually doing this right...")
    if b == true then
        return true
    endif
    return false
endfunction

function Stuff takes nothing returns nothing
    call KT_Add(function Callback, 0, 1)
    call BJDebugMsg("Debugging Stuff") // Doesn't do anything, unless I call it with GUI.
endfunction
function myFunct takes nothing returns nothing
    local trigger t = CreateTrigger( )
    call TriggerAddAction(t, function Stuff)
    call BJDebugMsg("Debugging myFunct") // Doesn't do anything
endfunction

 

[Azlier]

scope Blah initializer Stuff

function Callback takes nothing returns boolean // Only works if I call "Stuff" with a GUI trigger.
    local integer Data = KT_GetData()
    local boolean b = false
    call BJDebugMsg("Just a test, to see if I'm actually doing this right...")
    if b == true then
        return true
    endif
    return false
endfunction

function Stuff takes nothing returns nothing
    call KT_Add(function Callback, 0, 1)
    call BJDebugMsg("Debugging Stuff") // Doesn't do anything, unless I call it with GUI.
endfunction

endscope

 

[Jesus4Lyf]

Azlier is right.

Here's a neat example.

scope Cool initializer OnInit
    // Some data you'd like to attach. This might store the
    // unit and speed in a knockback system for example.
    //
    // In this case, it only stores a message to display,
    // and how many times it has displayed so far.
    private struct Data
        integer count = 0
        string message = null
    endstruct
    
    // The callback.
    private function Callback takes nothing returns boolean
        // Load KT attached data.
        local Data d = Data(KT_GetData())
        
        // Do things.
        set d.count = d.count + 1
        call BJDebugMsg(d.message)
        
        // If it is time to end this...
        if d.count == 5 then
            call d.destroy()
            return true
        endif
        
        // Default: keep ticking
        return false
    endfunction
    
    private function OnInit takes nothing returns nothing
        // Make a struct instance and pass it to Callback through KT every 0.5 seconds.
        local Data d = Data.create()
        set d.message = "Hi!"
        call KT_Add(function Callback, d, 0.5)
        
        // New one (completely separate to above):
        set d = Data.create()
        set d.message = "Message #2!"
        call KT_Add(function Callback, d, 0.7)
    endfunction
endscope

 

[Lyerae]

Alright, cool. Thanks guys!
Hehe, I know how to use KT2 now...

 

[Jesus4Lyf]

Hehe, I know how to use KT2 now...

Best of luck. :thup:

Hm, also, feel free to ask questions in the KT2 thread directly. It is preferred to JASS Help, so other users can see it in the thread if they need similar assistance...

 

[SanKakU]

function Callback takes nothing returns boolean
    local integer Data = KT_GetData() //Get attached data. If you don't want it, just call KT_GetData().
    //Do stuff.
    if something then
        //Returning true makes the system stop calling the callback.
        return true
    endif
    //Returning false tells the system to call the function when the timer expires again.
    return false
endfunction

function Omg takes nothing returns nothing
    call KT_Add(function Callback, data, period)
endfunction

//ok first of all...WHAT IS DATA????????!?!?!??!

//secondly...what's the difference between data and period?
//i mean seriously...if this is an alternative to triggersleepaction
//then i am totally baffled.  last i checked that function takes one number!

 

[Jesus4Lyf]

Sir, do you know structs?

 

[SanKakU]

trying to figure them and timers out at the same time, i guess...

 

[Jesus4Lyf]

A simple "wait" using KT2 will always look something like this:

private function AfterWait takes nothing returns boolean
    local <structtype> d=<structtype>(KT_GetData())
    
    // Do things.
    
    call d.destroy()
    return true // No returning false for a simple wait, it only fires one time.
endfunction

function Something tak...
    local <structtype> d=<structtype>.create()

    //Do things before the wait.
   
    set d.<something>=<some value you'll need to use after the wait>
    //... more of these
   
    call KT_Add(function AfterWait, d, <wait duration>)
endfunction

You should post what you PM'd me here instead. It is easier to ask publicly for advice than to respond to 50 PMs...
... And as I said just before your post, I prefer people asking questions in the system thread.

PS. Nothing is as easy to use as TriggerSleepAction.

 

[Lyerae]

But doesn't [ljass]TriggerSleepAction[/ljass] not work properly?

 

[kingkingyyk3]

TriggerSleepAction is not accurate.

 

[Lyerae]

Yeah, that's what I ment... I really need to word things better. >.<

 

[SanKakU]

right.
i'll repost it there.