AIDS (array) structs + array variables

[luorax]

Okay, I have a question:
How can I use array variables in a sruct which extends array? I have an AIDS struct which contains various datas about the questgiver units, and I need array members in it. I'm using two struct to achieve it, but what's your opinion? I don't want to use dynamic arrays, because their limitations.

This is a part of my script:

    private struct QuestGiverData 
        effect array SFX[12]
        private method onDestroy takes nothing returns nothing
            local integer li = 0
            loop
                exitwhen li > 11
                call DestroyEffect(.SFX[li])
                set .SFX[li] = null
                set li = li + 1
            endloop
        endmethod
    endstruct
    
    private struct QuestGiverStruct extends array
        readonly QuestGiverData Data
        method AIDS_onCreate takes nothing returns nothing
            set .Data = QuestGiverData.create()
        endmethod
        static method AIDS_filter takes unit u returns boolean
            return GetOwningPlayer(u) == QUEST_PLAYER_1 or GetOwningPlayer(u) == QUEST_PLAYER_2
        endmethod
        method AIDS_onDestroy takes nothing returns nothing
            call .Data.destroy()
        endmethod
        //! runtextmacro AIDS()
    endstruct

But what else should I do to improve it?

 

[kingkingyyk3]

Use :

type QuestGivenData extends effect array [13]

 

[luorax]

13 should be 12, not? I need 1 effect per player.

 

[Romek]

Yes, [13] should be [12]. I assume that's a typo.
Use [12, XYZ] to increase the instance rate of that array. Replace XYZ with the number of array indices to be taken up by the variable. You should use a multiple of 8190, though it doesn't really matter.
The instance limit will be XYZ/12.

 

[kingkingyyk3]

Just an example.

 

[Jesus4Lyf]

I don't think anyone mentioned that QuestGivenDatas would then need to be .created and .destroyed.

But yes, this is the way to do it. You can keep the creation/destruction in the AIDS_onCreate and AIDS_onDestroy methods.

 

[luorax]

Okay, this is how my struct looks like now:

type QuestGiverData extends effect array [12]
    
    private struct QuestGiverStruct extends array
        readonly QuestGiverData Data
        method AIDS_onCreate takes nothing returns nothing
            set .Data = QuestGiverData.create()
        endmethod
        static method AIDS_filter takes unit u returns boolean
            return GetOwningPlayer(u) == QUEST_PLAYER_1 or GetOwningPlayer(u) == QUEST_PLAYER_2
        endmethod
        method AIDS_onDestroy takes nothing returns nothing
            local integer li = 0
            loop
                exitwhen li > 11
                call DestroyEffect(.Data[li])
                set .Data[li] = null
                set li = li + 1
            endloop
            call .Data.destroy()
        endmethod
        //! runtextmacro AIDS()
    endstruct

Also, thanks + rep to everyone.